VB多线程实例教程

2008年03月09日

VB多线程实例教程

进程：是指程序在一个数据集合上运行的过程，是操作系统进行资源分配和调度运行的一个独立单位，简单来说进程就是程序的一次执行。

进程的两个基本属性：1.进程是一个可拥有资源的独立单位；2. 进程同时又是一个可以独立调度和分配的基本单位。

操作系统中引入进程的目的是为了使多个程序并发执行，以改善资源利用率及提高系统的吞吐量。

线程：线是进程中的一个实体，是被系统独立调度和分配的基本单位。线程自己基本上不拥有系统资源，只拥有一些在运行中必不可少的资源，但它可与同属一个进程的其他线程共享进程所拥有的全部资源。同一个进程中的多个线程之间可以并发执行。

问题实现：

VB可不可以创建多线程呢？答案：VB本身不可以，但用API函数VB可以实现。

在VB中创建线程用到以下几个API函数：

'创建线程API

'此API经过改造，lpThreadAttributes改为Any型，lpStartAddress改为传值引用：

'因为函数入口地址是由形参变量传递，如果用传址那将传递形参变量的地址而不是函数的入口地址

' 参数dwStackSize为应用程序堆栈大小，lpStartAddress为函数入口地址

Private Declare Function CreateThread Lib "kernel32" (ByVal lpThreadAttributes As Any, ByVal dwStackSize As Long, ByVal lpStartAddress As Long, lpParameter As Any, ByVal dwCreationFlags As Long, LpthreadId As Long) As Long

'终止线程API

Private Declare Function TerminateThread Lib "kernel32" (ByVal hThread As Long, ByVal dwExitCode As Long) As Long

'激活线程API,参数hThread为CreateThread创建的线程句柄

Private Declare Function ResumeThread Lib "kernel32" (ByVal hThread As Long) As Long

'挂起线程API

Private Declare Function SuspendThread Lib "kernel32" (ByVal hThread As Long) As Long

原理先不说了,先举个示例,有兴趣的话大家可以一起讨论

1.新建一个工程,类型选择ActiveX Exe,工程重命名为TestExe
在工程中添加一个Form,放上一个Timer控件.
将Class1改名为clsTest,注意其Instancing要设置为5-MultiUse, 以下是其代码:

Option Explicit
Private Declare Sub Sleep Lib \"kernel32\" (ByVal dwMilliseconds As Long)
Private WithEvents oTimer As Timer
Private frmTmp As Form1
Private lTotalLoop As Long
Private bDoStop As Boolean
Private lInterval As Long

Public Event Progress(ByVal lProgress As Long)

Public Sub StartSub(ByVal lTotal As Long)
lTotalLoop = lTotal
oTimer.Enabled = True
End Sub

Public Sub StopSub()
bDoStop = True
End Sub

Private Sub Class_Initialize()
    Set frmTmp = New Form1
    Load frmTmp
    Set oTimer = frmTmp.Timer1
    oTimer.Enabled = False
    bDoStop = False
    lInterval = 1
End Sub

Private Sub DoLoop()
    Dim i As Long
    For i = 0 To lTotalLoop
        Sleep (lInterval)
        RaiseEvent Progress(i)

        If bDoStop = True Then
            Exit Sub
        End If

    Next
End Sub

Private Sub Class_Terminate()
    Unload frmTmp
    Set frmTmp = Nothing
    Set oTimer = Nothing
End Sub

Private Sub oTimer_Timer()
oTimer.Enabled = False
DoLoop
End Sub

Public Property Get lMillisecs() As Long
lMillisecs = lInterval
End Property

Public Property Let lMillisecs(ByVal vNewValue As Long)
lInterval = vNewValue
End Property

在TestExe Property(工程属性)的Threading Model中,设置Thread per Object,或者选择Thread pool中设置大于1的数值.如把Thread pool设置为2, 则调用此ActiveX Exe最多能同时有两个线程, 更多的请求将放置于队列中.
编译TestExe

下面来测试我们的多线程程序:

新建一个Standard Exe工程,在Reference中选择刚刚做好的TestExe.exe
在Form1中添加两个ListBox,两个CommandButton,Command1为开始,Command2为停止
以下是Project1.Form1的代码:

Option Explicit
Private WithEvents oTest1 As TestEXE.clsTest
Private WithEvents oTest2 As TestEXE.clsTest

Private Sub Command1_Click()
    Set oTest1 = New TestEXE.clsTest
    oTest1.lMillisecs = 100
    oTest1.StartSub (1000)

    Set oTest2 = New TestEXE.clsTest
    oTest2.lMillisecs = 100
    oTest2.StartSub (1000)
End Sub

Private Sub Command2_Click()
oTest1.StopSub
oTest2.StopSub
End Sub

Private Sub Form_Unload(Cancel As Integer)
Set oTest1 = Nothing
Set oTest2 = Nothing
End Sub

Private Sub oTest1_Progress(ByVal lProgress As Long)
List1.AddItem lProgress
List1.ListIndex = List1.ListCount - 1
End Sub

Private Sub oTest2_Progress(ByVal lProgress As Long)
List2.AddItem lProgress
List2.ListIndex = List2.ListCount - 1
End Sub

启动Project1,点击Command1,怎么样,看见来效果了吗? 试着把TestExe的Thread pool改成1看看会怎么样? 这是我认为最简单且稳固的多线程实现方法了,大家有什么好的想法欢迎留言.

本文转自：SEO基地

本文链接：http://www.11zhuce.com/seo/273.html